@echo off&color 1f
title 安装辅助包 1.7 先确认版
setlocal EnableDelayedExpansion
mode con: cols=150

set p=%~dp0
if not "%p:~-10%"=="\AutoCall\" (
echo.
echo  “安装.bat”所在目录不对，请在辅助包的 AutoCall 目录里运行“安装.bat”！
echo.
pause
exit
)
cd /d %p%

:L0
echo.
echo  安装即将辅助包内容复制到手机。定制是指在电脑上定制辅助包的内容，因此定制后还需要安装

:L1
echo.
echo  安装前请将手机连接电脑并打开手机的 USB 存储设备，或者将 SD/TF 卡插到电脑读卡器
echo  ____________________________________________________________________________________
echo.
echo  1 安装（输入 1 按回车或直接按回车）
echo.
echo  2 定制（输入 2 按回车）
echo.
echo  3 自定义安装（输入有 AutoCall 目录的路径，例如：f:\abc）
echo.
set c1=
set /p c1= 请输入: 
echo.
if "%c1%"=="" goto L2
if "%c1%"=="1" goto L2
if "%c1%"=="2" goto START2
if "%c1%"=="0" (cls&&goto L0)
echo %c1%|findstr /i "^[a-z]$">nul&&set c1=%c1%:||@
if exist %c1%\AutoCall (
	set drive=%c1%
	goto START1
) else (
	echo.
	echo  目录 %c1%\AutoCall 不存在，请检查后再安装！
	echo.
	pause
	echo.
	goto L1
)

:L2
for /f "delims=" %%a in ('wmic logicaldisk get deviceid^,drivetype^,size^|findstr /rc:"[A-Z]: *2  *[1-9]"') do (
	set p=%%a
	set drive=!p:~0,2!
	if exist !drive!\AutoCall goto START1
)
echo.
echo  未找到有 AutoCall 目录的移动磁盘，请检查后再安装！
echo.
pause
echo.
goto L1

:START2
echo.
echo  __________________________________________________________________________
echo.
echo  0   全部恢复默认
echo.
echo  10  s1.mp3：您的按键已经收到，请再按数字 9 确认（默认）
echo  11  s1.mp3：您的按键已经收到，为保证按键正确，请再按数字 9
echo.
echo  20  s2.mp3：按 7 换化名、按 8 多人三退和按 0 留言（默认）
echo  21  s2.mp3：按 7 换化名和按 0 留言
echo.
echo  30  ts.mp3：如果您周围的亲友已经同意，请根据语音提示为他三退（默认）
echo  31  ts.mp3：请注意：代他人三退必须征得本人同意，请根据语音提示为下一位三退
echo  32  ts.mp3：请注意：代他人三退必须征得本人同意，下面开始另一人的三退
echo  33  ts.mp3：如果您周围的亲友已经同意，请按照下面的语音开始为他三退
echo.
echo  40  gd.mp3：可发短信三退 + 翻墙软件介绍 + 送您平安秘诀（默认）
echo  41  gd.mp3：定制版
echo  42  gd.mp3：去定制（按任意顺序和组合生成固定语音 gd.mp3）
echo.
echo  50  禁止.txt：（默认）
echo  51  禁止.txt：过滤的不合适化名更多
echo.
echo  输入开头数字并按回车，直接按回车返回上级菜单
echo.
set c2=
set /p c2= 请输入: 
echo.

set q=.\ /y /k /f /r
if "%c2%"=="0" (
	xcopy 备用\化名确认备用\默认\*.* %q%
	xcopy 备用\完成提示备用\默认\*.* %q%
	xcopy 备用\多人三退备用\默认\*.* %q%
	xcopy 备用\固定语音备用\默认\*.* %q%	
	xcopy 备用\禁止文件备用\默认\*.* %q%
) else if "%c2%"=="10" (
	xcopy 备用\化名确认备用\默认\*.* %q%
) else if "%c2%"=="11" (
	xcopy 备用\化名确认备用\备用\*.* %q%
) else if "%c2%"=="20" (
	xcopy 备用\完成提示备用\默认\*.* %q%
) else if "%c2%"=="21" (
	xcopy 备用\完成提示备用\备用\*.* %q%	
) else if "%c2%"=="30" (
	xcopy 备用\多人三退备用\默认\*.* %q%
) else if "%c2%"=="31" (
	xcopy 备用\多人三退备用\备用1\*.* %q%
) else if "%c2%"=="32" (
	xcopy 备用\多人三退备用\备用2\*.* %q%
) else if "%c2%"=="33" (
	xcopy 备用\多人三退备用\备用3\*.* %q%	
) else if "%c2%"=="40" (
	xcopy 备用\固定语音备用\默认\*.* %q%
) else if "%c2%"=="41" (
	xcopy 备用\固定语音备用\定制版\*.* %q%
) else if "%c2%"=="42" (
	goto START3	
) else if "%c2%"=="50" (
	xcopy 备用\禁止文件备用\默认\*.* %q%
) else if "%c2%"=="51" (
	xcopy 备用\禁止文件备用\备用\*.* %q%
)
echo.
if "%c2%"=="" (goto L1) else (pause&&goto START2)

:START3
echo.
echo  ________________________________________________________________
echo.
echo  1 您也可以稍后发短信三退，短信内容请用数字：“1”表示退党，“2”退团，“3”退队，后面再加上化名。注意，帮亲朋好友三退必须经过本人同意。
echo.
echo  2 您也可以使用翻墙软件“自由门”上退党网站直接三退，“自由门”软件有电脑版和手机版，使用“自由门”可以看到在国内被封锁的许多新闻和信息。
echo.
echo  3 再送您一个平安的秘诀，请您牢牢记住，就是：“法轮大法好，真善忍好”。记住他，在关键时刻，他能使您逢凶化吉，遇难呈祥。
echo.
echo  输入数字的顺序组合（例如 123、213、23 等）并按回车，直接按回车返回上级菜单
echo.
set s=
set /p s= 请输入: 
echo.
if "%s%"=="" goto START2
set c1=%s:~0,1%
set c2=%s:~1,1%
set c3=%s:~2,1%
set p=
if not "%c1%"=="" set p=%p%备用\固定语音备用\gd%c1%.mp3+
if not "%c2%"=="" set p=%p%备用\固定语音备用\gd%c2%.mp3+
if not "%c3%"=="" set p=%p%备用\固定语音备用\gd%c3%.mp3+
set p=%p:~0,-1%
set q=备用\固定语音备用\定制版\gd.mp3
copy /b %p% %q%  >nul 2>nul
if errorlevel 0 (
echo  已生成：%~dp0%q%
echo.
xcopy %q% .\ /y /k /f /r
echo.
)
pause
goto START2

:START1
if "%drive%\AutoCall"=="%cd%" (
	echo.
	echo  目标目录和源目录相同，不能将辅助包复制到自身，请检查后再安装！
	echo.
	pause
	echo.
	goto L1
)

set p=%drive%\AutoCall
set t1=%p%\时间.txt
set t2=%p%\时间_旧.txt
if exist %t1% (
	fc %t1% 时间.txt  >nul 2>nul
	if errorlevel 1 (
		copy %t1% %t2% /y  >nul 2>nul
		echo %t1% 备份为 %t2%
		del %t1% /f /q >nul 2>nul
	)
)

set t1=%p%\语音
set t2=%p%\语音_旧
if not exist %t2% (
	for /r %t1% %%i in (*.*) do goto LL
	md %t2%
)
:LL
set bak=0
if exist %t1% if not exist %t2% (
	echo %t1% 改名为 %t2%
	move %t1% %t2%
	set bak=1
	for /f "delims=" %%a in (时间.txt) do (
		set a=%%a
		for /f "tokens=1-5 delims=," %%b in ("!a!") do (
			set c=%%c
			set d=%%d
			set e=%%e
			set f=%%f
			if "!d!"=="" (set b=!c!) else if "!e!"=="" (set b=!d!) else if "!f!"=="" (set b=!e!) else set b=!f!
			if not "!b:~0,1!"=="（" if exist %t2%\!b! xcopy %t2%\!b! %t1%\ /y /k /f /r
		)	
	)
	if exist %t2%\*.txt xcopy %t2%\*.txt %t1%\ /y /k /f /r
)

set b=0
set q=说明.htm
if exist %p%\%q% (
	for /f "skip=5 tokens=1,2" %%i in ('dir %p%\%q% /tw') do set date=%%i%%j&&goto END
:END
	for /f "skip=5 tokens=1,2" %%i in ('dir %q% /tw') do set date2=%%i%%j&&goto END2
:END2	
	if "%date%"=="%date2%" (set b=1) else if "%date%" LSS "%date2%" (set b=3) else (set b=2)
)
rem 0:1.5之前升到1.5之后 1:同版 2:降级 3:升级
if not %b%==1 (
	del %p%\s0-*.*  /f /q >nul 2>nul
	del %p%\说明.htm /f /q >nul 2>nul
	del %p%\安装.bat /f /q >nul 2>nul
	del %p%\版本.txt /f /q >nul 2>nul
	del %p%\AutoCall.md5 /f /q >nul 2>nul
	rd %p%\备用 /s /q >nul 2>nul
	xcopy 语音\*.* %p%\语音\ /y /k /f /r
)
del %p%\优化.xml /f /q >nul 2>nul
del %p%\禁止.txt /f /q >nul 2>nul
xcopy ????.mp3 %p% /y /k /f /r
xcopy *.* %p% /y /k /f /r /s /e /d
echo.
if %bak%==0 (echo  安装完成！) else echo 安装完成！注意：原语音目录已改名为“语音_旧”，当前语音目录只保留了时间表中有定义的语音，请拷贝其它需要的语音到“语音”目录！
echo.
pause
echo.
goto L1
